set命令

@echo off  
set
pause  

@echo off  
set var=我是值  
echo %var%  
pause 

@echo off
set /p input=请输入一个字符串:
echo,%input%
pause

@echo off
for %%i in (bat home) do (
echo,%%i
)
pause

@echo off
for %%i in (bat home) do (
set /p =%%i<nul
)
pause

@echo off
echo bbs.bathome.net
set /p =光标回退（非cls清屏）动画效果演示：<nul
for /l %%i in (1,1,10) do (
    set /p =%%i<nul
    set /p =<nul
    ping -n 2 127.1 >nul
)
echo,
pause

@echo off
set /a n=3%%2
echo %n%
pause

@echo off
set /a "m=1<<10"
set /a n=1"<<"10
echo %m% %n%
pause

@echo off&setlocal enabledelayedexpansion
set /p str=输入的两数为：
set /a num_1=0,num_2=0,num=1,v=0
for %%a in (%str%) do (
    set /a n+=1
    for /f "tokens=1,2 delims=." %%b in ("%%a") do (
        set "_!n!=%%b"
        if "%%c" equ "" (
           set ".!n!=00"&set /a m+=1
           if !m! equ 2 set "flag=a"
           ) else (
           set "a=%%c00"&set "a=!a:~,2!"
           set ".!n!=!a!"
        ) 
     )
)
for %%a in (+#h -#c) do (
    for /f "tokens=1,2 delims=#" %%b in ("%%a") do (
        if "%_1:~,1%" equ "-" set "k1=-"
        if "%_2:~,1%" equ "-" set "k2=-"
        set /a %%c1=_1%%b_2,%%c2=!k1!1%.1%%%100%%b!k2!1%.2%%%100
        if !%%c1! lss 0 (
           if !%%c2! leq -100 set /a %%c2+=100,%%c1-=1
           ) else (
           if !%%c1! equ 0 (
              if !%%c2! lss 0 set "%%c1=-0"&set "a=!%%c2!"&set "%%c2=!a:-=!"
              ) else (
              if !%%c2! lss 0 set /a %%c2+=100,%%c1-=1
           )
         )
         if !%%c2! geq 100 set /a %%c2-=100,%%c1+=1 
    )
)
for %%a in (h2 c2) do (
    set "a=!%%a!"&set "a=!a:-=!"&set %%a=!a!
    if !a! lss 10 set "%%a=0!a!"
)
echo 其和为：%h1%.%h2%&echo 其差为：%c1%.%c2%&set /a n=0
if defined flag set ".1="&set ".2="
for %%a in (1 2) do (
    if "!_%%a!" equ "0" (
       set "_%%a="&set /a .%%a=1!.%%a!%%100
       ) else (
       if "!_%%a!" equ "-0" (
          set "_%%a=-"
          ) else (
          set "a=!_%%a!"&set "a=!a:-=!"
          set /a n+=1&call :lp
       )
    )
    if "!.%%a!" neq "" set "a=!.%%a!"&call :loop&set ".%%a=!a!"
)
set /a num1=3-num_1+num_2,m=4-v
if defined flag set /a m=0
if %num1% leq 0 set /a num1=2
for /l %%a in (1,1,%num1%) do set /a num*=10
set /a s=%_1%%.1%*num/%_2%%.2%,j=%_1%%.1%*%_2%%.2%
if %j% lss 0 set "j=%j:-=%"&set "jk=-"
if %s% lss 0 set "s=%s:-=%"&set "sk=-" 
if %m% neq 0 if "!j:~%m%!" equ "" set "j=0000%j%"&set "j=!j:~-%m%!"
if %s% lss %num% set "s=%num:~1%%s%"&set "s=!s:~-%num1%!"
if %m% neq 0 set "j=!j:~,-%m%!.!j:~-%m%,2!"
set "s=!s:~,-%num1%!.!s:~-%num1%,2!
for %%a in (s j) do (
    set "a=!%%a!"
    if "!a:.=!" equ "!a!" (
       set "%%a=!%%a!.00"
       ) else (
       if "!a:~-2,1!" equ "." set "%%a=!%%a!0"
    )  
    if "!a:~,1!" equ "." set "%%a=0!%%a!"
)
echo 其积为：%jk%%j%&echo 其商为：%sk%%s%
pause>nul&goto :eof
:lp
set /a num_%n%+=1&set "a=%a:~1%"
if defined a goto lp
goto :eof
:loop
if "%a:~-1%" equ "0" set "a=%a:~,-1%"&set /a v+=1&goto loop

@echo off
setlocal enabledelayedexpansion
REM 全部转换成大写字母
set str=http://bbs.BATHOME.net
set up=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
for %%i in (%up%) do (
set str=!str:%%i=%%i! )
echo %str%
pause

@echo off
setlocal enabledelayedexpansion
REM 全部转换成小写字母
set str=http://bbs.BATHOME.net
set low=a b c d e f g h i j k l m n o p q r s t u v w x y z
for %%i in (%low%) do (
set str=!str:%%i=%%i! )
echo %str%
pause

@echo off
REM 利用重定向把命令结果（单行字符串）赋值给变量
ping 127.0.0.1 | findstr "%%" > "%temp%\ping.txt"
set /p PacketLoss=<"%temp%\ping.txt"
echo %PacketLoss%
pause

@echo off
REM 利用for语句把命令结果（单行字符串）赋值给变量
for /f "delims=" %%i in ('ping 127.0.0.1 ^| findstr "%%"') do (
set "PacketLoss=%%i"
)
echo %PacketLoss%
pause

@echo off
for %%i in (a.txt c.txt b.txt e.txt) do (
set #%%i=%%i
)
for /f "tokens=2 delims==" %%i in ('set #') do (
echo %%i
)
pause