易语言qq全自动点赞 易语言实现QQ全自动批量点赞功能

.版本 2
.支持库 iext
.支持库 HtmlView
.支持库 spec
.程序集 窗口程序集1
.程序集变量 停止变量, 逻辑型
.子程序 __启动窗口_创建完毕
' 不允许多个QQ登录,不然每次需要手动选择点赞的号
.子程序 _导入按钮_被单击
.局部变量 分割文本, 文本型, , "0"
.局部变量 文本, 文本型
.局部变量 i1, 整数型
.局部变量 索引, 整数型
通用对话框1.初始目录 ＝ 取运行目录 ()
.如果真 (通用对话框1.打开 () ＝ 真)
  超级列表框1.全部删除 ()
  文本 ＝ 到文本 (读入文件 (通用对话框1.文件名))
  分割文本 ＝ 分割文本 (文本, #换行符, )
  .计次循环首 (取数组成员数 (分割文本), i1)
    系统_处理事件 ()
    索引 ＝ 超级列表框1.插入表项 (超级列表框1.取表项数 () ＋ 1, 到文本 (超级列表框1.取表项数 () ＋ 1), , , , )
    超级列表框1.置标题 (索引, 1, 分割文本 [i1])
  .计次循环尾 ()
.如果真结束
.子程序 _点赞按钮_被单击
QQ个人资料_批量点赞 ()
.子程序 QQ个人资料_批量点赞
.局部变量 局_当前行, 整数型
.局部变量 局_句柄1, 整数型
.局部变量 局_句柄_整组, 整数型, , "0"
.局部变量 局_横坐标, 整数型
.局部变量 局_纵坐标, 整数型
.局部变量 N, 整数型
.局部变量 局_所有QQ_文组, 文本型, , "0"
局_横坐标 ＝ 336
局_纵坐标 ＝ 334
.计次循环首 (超级列表框1.取表项数 (), N)
  .如果真 (停止变量 ＝ 真)
    返回 ()
  .如果真结束
  加入成员 (局_所有QQ_文组, 超级列表框1.取标题 (N － 1, 1))
.计次循环尾 ()
' -----------------------
窗口_模糊遍历窗口 (, , “的资料”, 局_句柄_整组)
系统_处理事件 ()
.如果真 (取数组成员数 (局_句柄_整组) ＞ 0)
  .计次循环首 (取数组成员数 (局_句柄_整组), N)
    窗口_关闭 (局_句柄_整组 [N])
  .计次循环尾 ()
.如果真结束
' -----------------------
.计次循环首 (取数组成员数 (局_所有QQ_文组), N)
  .如果真 (停止变量 ＝ 真)
    返回 ()
  .如果真结束
  超级列表框1.现行选中项 ＝ N － 1
  超文本浏览框1.地址 ＝ “tencent://ContactInfo/?subcmd=ViewInfo&puin=0&uin=” ＋ 局_所有QQ_文组 [N]
  .计次循环首 (10, )
    延迟 (1000)
    局_句柄1 ＝ 窗口_取句柄_模糊 (“的资料”, “TXGuiFoundation”)
    系统_处理事件 ()
    .如果真 (局_句柄1 ＞ 0)
      跳出循环 ()
    .如果真结束
  .计次循环尾 ()
  超级列表框1.置标题 (N － 1, 2, “√”)
  .如果真 (局_句柄1 ＝ 0)
    信息框 (“打开QQ个人资料失败”, #错误图标, “注&意：”)
    点赞按钮.禁止 ＝ 假
    返回 ()
  .如果真结束
  ' --------------
  程序_延时 (1000)
  .计次循环首 (10, )
    系统_处理事件 ()
    鼠标_消息 (局_句柄1, 局_横坐标 ＋ 100, 局_纵坐标, 2, 1)
    系统_处理事件 ()
    鼠标_消息 (局_句柄1, 局_横坐标, 局_纵坐标, 1, 1)
    程序_延时 (300)
    系统_处理事件 ()
    ' 调试输出 (“ 鼠标_消息 ”)
  .计次循环尾 ()
  程序_延时 (1000)
  窗口_关闭 (局_句柄1)
.计次循环尾 ()
信息框 (“完成”, 0, “注&意：”)
.子程序 _停止按钮_被单击
停止变量 ＝ 真